% File:   misc.pl
% Author: Dilian Gurov, KTH CSC

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

% Föreläsning 4: Prolog-specifiska konstruktioner
%
% - Negation
% - Snitt
% - Aritmetik
% - I/O: read, write, nl
% - Kontrollpredikat: fail, call
% - Metapredikat: assert, retract
%
% Läs boken: kap. 5, 9, 10

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

% - Negation i (SWI) Prolog

snygg(kia).

% ?- snygg(nisse).

osnygg(X) :- \+ snygg(X).

% ?- osnygg(nisse).
% ?- osnygg(kia).
% ?- osnygg(X).                         Sant om ingen är snygg!!!

in(H, [H | _]).
in(X, [_ | T]) :- in(X, T).

% ?- in(X, [1, 2]), \+ in(X, Y).

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

% - Snitt
%
% Exempel: max(X, Y, Z)

max(X, Y, X) :- Y<X.
max(X, Y, Y).

% ?- max(5, 3, X).
%
% Vad händer om vi frågar efter flera svar?

maxCut(X, Y, X) :- Y<X, !.
maxCut(X, Y, Y).

% ?- maxCut(5, 3, X).

% Exempel från Learn Prolog Now!

s(X, Y) :- q(X, Y).
s(0, 0).

q(X, Y) :- i(X), !, j(Y).
q(4, 4).

i(1).
i(2).

j(1).
j(2).
j(3).

% ?- s(X, Y).

% Ett till exempel på grönt snitt: lookup(D, T)

lookupCut(D, leaf(D)) :- !.
lookupCut(D, branch(D, _, _)) :- !.
lookupCut(D, branch(_, LT, _)) :- lookupCut(D, LT), !.
lookupCut(D, branch(_, _, RT)) :- lookupCut(D, RT).

isDTree(branch(-3,branch(4,leaf(8),leaf(-2)),leaf(7))).

% ?- isDTree(T), lookupCut(4, T).
% ?- isDTree(T), lookupCut(5, T).
% ?- isDTree(T), lookupCut(X, T).                            Bara en lösning!!!
% ?- lookupCut(anna, T), lookupCut(4, T), lookupCut(bo, T).    Ingen lösning!!!

% Exempel på rött snitt:
% Vad åstadkommer följande regel?

isnygg(X) :- snygg(X), !, fail.
isnygg(X).

% ?- isnygg(nisse).
% ?- isnygg(kia).
% ?- isnygg(X). 

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

% - I/O i Prolog

% ?- read(X+Y), write(Y+3).

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

% - Kontrollpredikat

not(X) :- call(X), !, fail.
not(X).

% ?- not(snygg(nisse)).

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

% - Metapredikat

% ?- assert(cool(anna)).
% ?- assert(hip(X) :- cool(X)).
% ?- hip(anna).
% ?- retract(cool(anna)).
% ?- hip(anna).

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%