IX1300 HT2012 Lektion 4

Trigonometriska funktioner  i Mathematica

Sinus, cosinus & tangens

Sinusfunktionen

Sin[x]

Exakt och numeriskt värde

Sin[Pi/3]
N[%]
N[Sin[Pi/3], 10]

En tabell med värden

värden=Table[k Pi/12,{k,0,12}];

värden

Map

Vi kan mappa en funktion på tabellen värden

Map[Sin,värden]

?Map

Vi kan skriva mappningen så här också

Sin/@ värden

Så här kan vi också skriva (kompakt men inte så tydligt kanske):

N/@ %

Cosinus

Cos/@ värden

En tabell med exakta värden

Grid[{{"ϕ"},
Table[k Pi/12,{k,0,12}],
{"Sin ϕ"},
Table[Sin[k Pi/12],{k,0,12}]},Frame->All]

Tangens

Tan/@ värden

Vinkel i grader

?Degree

Cos[30 Degree]

Degree can be entered as Esc deg Esc:

Tan[45°]

Sin[60 Degree]==Sin[Pi/3]

Ekvationer

sin((π/3))==(3/x)

TraditionalForm[HoldForm[Sin[Pi/3]]==3/x]

{x1}=x/.Solve[Sin[Pi/3]==3/x]

Vad har x och x1 för värde?

{x1,x}

Några ekvationer till

ekv1=Sin[x]==Cos[x];
Solve[ekv1]

??

Solve[ekv1,x]

Solve[Sin[x]==0,x]

Reduce[Sin[x]==0,x]

Enhetscirkeln

?Circle

En enhetscirkel

Graphics[Circle[{0,0}]]

Axlar då?

enhetscirkel=Graphics[Circle[{0,0}],Axes->True]

Kvadratrot

Sqrt[2]==(Sqrt[2])

Ctrl+Shift+2

En linje

linje=Graphics[Line[{{0,0},{1/Sqrt[2],1/Sqrt[2]}}]]

Linjen och enhetscirkeln i samma figur

Show[enhetscirkel,linje]

En manipulation

Manipulate[Show[enhetscirkel,Graphics[Line[{{0,0},{Cos[fi],Sin[fi]}}]],PlotLabel->fi],
{fi,0,2Pi}]

Stegvis

Manipulate[Show[enhetscirkel,Graphics[Line[{{0,0},{Cos[fi],Sin[fi]}}]],PlotLabel->{fi,Sin[fi]}],
{{fi,Pi/4},-2Pi,2Pi,Pi/12}]

Vi lägger in en pil också

Manipulate[
Show[
enhetscirkel,
Graphics[Arrow[{{0,0},{Cos[fi],Sin[fi]}}]],
Graphics[{PointSize[Medium],Point[{Cos[fi],Sin[fi]}]}]
]
,
{fi,0,2Pi}]

Hur skapar vi en sinuskurva?

Manipulate[
Grid[
{{
Show[
enhetscirkel,
Graphics[Arrow[{{0,0},{Cos[fi],Sin[fi]}}]],
Graphics[{PointSize[Medium],Point[{Cos[fi],Sin[fi]}]}]
],
Show[Plot[Sin[fi],{fi,0,4Pi},PlotRange->{{0,4 Pi},{-1.1,1.1}}],Graphics[{PointSize[Medium],Point[{fi,Sin[fi]}]}]]
}}]
,
{fi,0,4Pi}]

Sinuskurvor

En sinuskurva y=sin(x), för xϵ [-10,10]

Plot[Sin[x],{x,-10,10},AxesLabel->{x,Sin x},AspectRatio->1/4]

X-axeln graderad i π i stället

sinus=Plot[Sin[x],{x,-2Pi,2Pi},AxesLabel->{x,Sin x},AspectRatio->1/4,Ticks->{{-2Pi,-Pi,0,Pi,2Pi,3Pi},{-1,1}}]

Cosinus-kurva

cosinus=Plot[Cos[x],{x,-2Pi,2Pi},AxesLabel->{x,"cos x"},AspectRatio->1/4,Ticks->{{-2Pi,-Pi,0,Pi,2Pi,3Pi},{-1,1}},PlotStyle->{Thick,Red}]

Sin x och Cos x i samma figur

Show[sinus,cosinus,AxesLabel->{x,"cos x och sin x"}]

Med lite text i figuren

Show[sinus,cosinus,AxesLabel->{x,"cos x och sin x"},Epilog->{Inset["cos (rött)",{-2.,.7}],Inset["sin (blå)",{3.,.7}]}]

En manipulation

Manipulate[Grid[{{Plot[A Cos[w0 t+ϕ],{t,0,0.02},PlotRange->{-10,10},AspectRatio->.4]},{A Cos[w0 t+ϕ]}}],{{A,10,"Amplitud"},2,10,.25},{{ w0,2Pi 440,"Vinkelfrekvens"}, Pi 220,8 Pi 440,10Pi},{{ϕ,-2/5  Pi,"Fasförskjutning"},-Pi,Pi,Pi/10}]

Summan av Sinuskurvor

Sin och cos

Manipulate[Grid[{
{"Sin och cos "},
{Plot[{Cos[ t],Cos[fasfi+ t]},{t,-2Pi,2Pi},PlotRange->{-2,2},PlotStyle->{{Blue,Thick},{Red,Thick}}]},{"Summan av kurvorna "},{Plot[Cos[ t]+Cos[fasfi+ t],{t,-2Pi,2Pi},PlotRange->{-2,2}]}}],{{fasfi,Pi/2},-Pi,Pi}]

Trigonometriska ekvationer

1

Solve[Sin[x]==Cos[x],x]

2

Solve[Sin[x]==1/2,x]

3

Solve[Sin[(x^2)]==1/2,x]

Figur

Plot[{1/2,Sin[(x^2)]},{x,-2Pi,2Pi}]